Der große AviSynth-Guide

Ein kurzes Danke an dieser Stelle, das Tutorial hat mir eben gerade nach langem Herumdoktern an einem Script den Schubs in die richtige Richtung gegeben, ich hatte da ein etwas größeres Problem, zwei Overlays zu verschiedenen Zeiten im Video unterzubringen, weil ich nicht wusste, dass man auch dem Image Start- und Endframes zuweisen kann. Nun weiß ich es.

Tschuldigung, aber nach Tagen Herumprobierens bleibe ich immernoch an der Noise-Funktion hängen. Ich habe die Schritte befolgt, "sox" auch wie angegeben verwendet, aber bei mir gibts es keine Änderungen. Ich habe eine einige Sekunden lange Rauschdatei von wav erfolgreich in so eine "xyz.noise-profile"-Datei umgewandelt, die einiges an Informationen enthält.

Während des Testens benötigt das Script einige Sekunden, was für mich bedeutet, daß ich die Syntax richig habe und daß das Rausch-Filtern angewendet wird, es sieht also alles richtig aus. Aber die umgewandelte Datei wird einfach nicht "entrauscht" - bzw nicht einmal geändert.

Manuelle Versuche, sprich, die sox.exe mittels Kommandozeile manuell ausführen zu lassen, reagieren ähnlich. Das heißt, wenn die Syntax richtig ist, ackert das Tool auch einige Sekunden, aber die WAV-Datei bleibt unverändert (auch das Änderungsdatum verändert sich nicht). Es muß also irgendwie am Output oder an der Syntax für das Output liegen.

Es scheint so, als würde sox das Rauschen zwar entfernen, das Ergebnis aber anschließend im Datennirvana verschwinden lassen.

Dokumentationen sind im Netz auch äußerst spärlich, wie ich finde.

"Der große Avisynth-Guide" hat mir zwar einiges gebracht, aber die Beispiele sind leider etwas unglücklich, "wackelig", und vor allem unpräzise beschrieben.
Vielleicht stell ich ich auch nur dämlich an?

Bisher hab ich die Audiobearbeitung immer mit [lexicon]Audacity[/lexicon] vorgenommen. Weil das aber jedes mal exakt dieselben Schritte sind, suche ich letztendlich einfach nur nach einer über [lexicon]MeGUI[/lexicon] und Avisynth automatisierten Methode, um meine Dateien umzuwandeln.

Folgende bisher manuelle Schritte würde ich gern automatisieren:
- extrahieren der zwei Tonspuren aus der AVI (von [lexicon]DXTory[/lexicon] kommend, das kann ich natürlich auch manuell machen)
- entrauschen der Kommentarspur (mono), wobei das Rauschen höchstwahrscheinlich von den Lüftern meines Rechners kommt und deshalb immer sehr gleichmäßig ist
- auf die Kommentarspur einen Kompressor anwenden, um das Gesprochene kraftvoller und gleichmäßiger zu machen
- mixen der Kommentarspur (mono, 0db) und der Spielton-Spur (stereo, -7db)
- am Anfang ein ein Fade-In und am Ende ein Fade-Out von jeweils zwei Sekunden einfügen (wie nachher in der Videospur auch)

Das klingt gar nicht kompliziert für so ein Avisynth-Script, aber ich hänge schon an Kommentarspur-Bearbeitung

Die anschließende Video- und Audio-Encodierung entsprechen ungefähr dem vom D-ae-M-o -N beschreibenen Vorgehensweise mit [lexicon]MeGUI[/lexicon] mittels AVS-Script.

Wenn der Beitrag hier soweit verfehlt wurde von mir, dann bitte nen neues Thema dafür eröffnen oder ins passende stecken. Danke

Ich hab mir mal so überlegt, ob man für Avisynth nicht sone Art Templates machen kann und hier vorstellen? Keine Ahnung ob das ein neues Thema braucht dieser Beitrag hier, weil es gehört Schlussendlich auch nur zu Avisynth.

Ich hab mir das folgendermaßen gedacht:
Ein Vorschaubild wie es im Endeffekt aussehen kann und darunter halt den Quelltext dazu. Damit man ne schöne Übersicht halt hat.

Ich hätte jetzt so auf die Schnelle 2 Stück die ich auch zeigen kann:

# Was ihr braucht ist
# - Eure Aufnahme
# - Ein Hintergrundbild
# - Ein schlichtes schwarzes Bild. Das könnt ihr mit Paint machen. 1 Pixel ist aber unzulässig. Also macht es nicht zu klein
# - Und ein Logo mit Transparenzeffekt (Optional)


#Das Rechnen bleibt nicht aus wer es so machen will.


#-------Laden der Quellen-----------
#Zuerst wird das Quellvideo wie gewohnt geladen und auf die richtige Größe angepasst
v0=AVISource("D:\capture1.avi", audio=false).ChangeFPS(30,1).Spline64Resize(1000,900)


#Dann kommt das Hintergrundbild das die Frameanzahl vom Quellvideo nimmt
v1=ImageSource("D:\BG.jpg",0,0,30,false).Spline64Resize(1920,1080).Loop(v0.Framecount)


#Dann als Feature, der Schatten der dann neben dem Quellvideo verläuft
v2=ImageSource("D:\black.jpg",0,0,30,false).Spline64Resize(1000,900)


# - Logo mit Tranzparenten Hintergrund laden
#Hier wird das Logo erst mal als gesamtes Bild geladen
p1p=ImageReader("D:\Logo.png")


#Während hier der Alphakanal angezeigt wird
p1a=ImageReader("D:\Logo.png",pixel_type="RGB32").ShowAlpha(pixel_type="RGB32")


# - Anordnung der Elemente auf dem Gesamtbild mit Overlay
#Als erstes pappen wir den Schatten etwas versetzt auf den Hintergrund
o1=Overlay(v1, v2 ,x=120, y=120, opacity=0.5)


#Dann das Video zentriet auf der Y Achse (900 + 2*90 = 1080)
o2=Overlay(o1, v0 ,x=90, y=90, opacity=1.0)


#Zu guter letzt wird das Logo draufgepappt mit der Alphamaske, die dafür sorgt das nur das Logo noch zu sehen ist.
#Alles zusamm wird als YV12 ausgegeben
Overlay(o2,p1p,mask=p1a, x=1243, y=590, opacity=1.0, output="YV12")

#------------- Mehrere Bilder/Videos nebeneinander -----------
#Hier braucht ihr einfach mehrere Quellen die ihr nebeneinander stellen wollt.
#Bedenkt das das Endvideo die Länge des längsten Videos hat


# - Quellen laden
v1=ImageSource("D:\R.jpg",0,0,30,false).Spline64Resize(360,1080)
v2=AVISource("D:\capture1.avi", audio=false).Spline64Resize(1200,1080)
v3=ImageSource("D:\L.jpg",0,0,30,false).Spline64Resize(360,1080)


# - Alles nebeneinander (Eignet sich für Ränder links und rechts)
stackhorizontal(v1,v2,v3).ConvertToYV12()


# ODER
# - Alles aufeinander (Eignet sich für Ränder oben und unten)
#stackvertical(v1,v2,v3).ConvertToYV12()

Verbesserungsvorschläge oder andere Templates würden mir auch gefallen

Zitat von TheFirgg

Zeit = Import("C:\Users\Michael\Desktop\MineSweeper_Zeit.avs")
Spiel = AVISource("C:\Users\Michael\Desktop\MineSweeper_Spiel.avi").AssumeFPS(180.000).ChangeFPS(30)
Overlay(Spiel,Zeit,x=0,y=320)

Reicht so.

Wofür die Variable Video erstellen, wenn du sie eh nirgends brauchst?

Noch ein schönes Template für AVS.

GameBoy und GameBoy Color Spiele im Retro Style für den VBA Emulator.

v0=AVISource("D:\capture1.avi", audio=false).ChangeFPS(30,1).Spline64Resize(970,873)
v1=ImageSource("D:\GB Display.bmp",0,0,30,false).Spline64Resize(1408,1080).Loop(v0.Framecount)


Overlay(v1, v0 ,x=219, y=103, opacity=1.0,output="YV12")

Das GameBoy Display hab ich selbst gepixelt. Wenn das Bild nicht mehr zum download bereitstehen sollte, mir einfach ne PN schreiben.
Das Display könnt ihr hier downloaden: GameBoy Display

EDIT: Hab sogar noch was dazu gepixelt und jetzt sieht das erst recht Retro aus: GameBoy Display Ultra Classic

AVISynth

EDIT:
So. Ich hab das ganze jetzt etwas verfeinert und werde das komplette Beispiel auch als Download anbieten mit den selbsterstellten Bildern von mir.
enthalten ist:

- Ein GB und GBC Display (Einmal mit Ummantelung und einmal ohne)
- Ein 10x10 Hintergrund und ein Glas Bild (Für die GB/GBC Display Scheibe)
- Eine Capture Aufnahme vom GB und GBC BIOS mit dem [lexicon]Lagarith[/lexicon] [lexicon]Codec[/lexicon] + die [lexicon]WAV[/lexicon] Datein
- Die Skripte. 4 Stück. Einmal mit und ohne Glas
- Und die von mir gepixelten Displays in der Original [lexicon]Auflösung[/lexicon] als Bitmap

Die Skripte sind nach dem Entpacken als Beispielmuster mit der jeweiligen BIOS Aufnahme verknüpft und können sofort encodiert werden in MeGUI.
Die Skripte sind beschrieben und sollten vor allem Anfängern zeigen was man damit machen kann. Ihr könnt den gesamten Inhalt für eure Videos nutzen und die Skripte euren Wünschen anpassen. Viel Spaß dabei.

Das File: downloaden (398 KB)

Wird mal wieder Zeit für AVISynth Spielerein ;D

Heute möcht ich euch zeigen wie ihr mit 2 Video und einem sogenanntes Vorlagevideo ein wirklich tollen Effekt erziehlen könnt. Es handelt sich um einen sehr einfachen Effekt, aber dennoch in AVISynth machbar. Weil der Trick bezieht sich wie man aus den Bildern schon unschwer erkennen kann um Masken. Sogenannte Alphamasken. Hier erzeugen wir eine Alphamaske auf ein Vorlagevideo. Bedeutet: Der Stern rotiert an sich und ist somit selbst ein Video. Der Sternclip besitzt ledeglich die Farben grün und weiß die dann entferntwerden und das eigentliche Video kann dafür ersetzt werden. Sollten eigentlich viele schon mal gemacht haben mit Bildern.

##############################
# 2 Videos mit ein Alphavideo
# ---------------------------
# v1 - das was in der Mitte angezeigt wird
# v2 - der rotierende mehrzackige Stern
#      (Bestehend aus nem grünen Hintergrund und einem weißen Stern)
# m1 - Alphamaske für v2 wird gesetzt auf weiß
# vv - v1 wird jetzt dank der Maske im rotierenden Stern angezeigt
# v3 - der Clip für das Hintergrundvideo
# m2 - Die Alphamaske wird resetet und neu auf grün gesetzt
# 
# Zum Schluss wird v3 als Hintergrundvideo spielen und das Video
# v1 wird im rotierenden Stern angezeigt.
#
##############################


v1=AVISource("Clip1.avi",Audio=false)
v2=AVISource("Alphaclip.avi").ConverttoRGB32()
m1=ColorKeyMask(v2,$FFFFFF,20).ShowAlpha(pixel_type="RGB32")


vv=Overlay(v1,v2,mask=m1).ConverttoRGB32()


v3=AVISource("Clip2.avi",Audio=false).ConverttoRGB32()
m2=ResetMask(vv).ColorKeyMask($00FF00,100)


Layer(v3,m2).ConverttoYV12()

V2 könnt ihr auch mit ein Bild ersetzen das die gleichen Eigenschaften aufweißt und ein [lexicon]Alphakanal[/lexicon] besitzt. Dann ist V2 nicht mehr dynamisch, sondern statisch und sieht wie folgt aus:

##############################
# 2 Videos mit ein Alphavideo
# ---------------------------
# v1 - das was in der Mitte angezeigt wird
# v2 - das Statische Bild mit dem mehrzackige Stern
#      (Bestehend aus nem grünen Hintergrund und einem weißen Stern)
# m1 - Alphamaske für v2 wird gesetzt auf weiß
# vv - v1 wird jetzt dank der Maske im rotierenden Stern angezeigt
# v3 - der Clip für das Hintergrundvideo
# m2 - Die Alphamaske wird resetet und neu auf grün gesetzt
# 
# Zum Schluss wird v3 als Hintergrundvideo spielen und das Video
# v1 wird im Stern angezeigt.
#
##############################


v1=AVISource("Clip1.avi",Audio=false)
v2=ImageReader("Alphabild.png")
m1=ImageReader("Alphabild.png", pixel_type="RPG32").ShowAlpha(pixel_type="RGB32")


vv=Overlay(v1,v2,mask=m1).ConverttoRGB32()


v3=AVISource("Clip2.avi",Audio=false).ConverttoRGB32()
m2=ResetMask(vv).ColorKeyMask($00FF00,100)


Layer(v3,m2).ConverttoYV12()

Die Funktionsweise bleibt aber die selbe. Ich wünsch euch viel Spaß beim ausprobieren und rumtüfteln ;D

Dank SaintzLP und seinen Problem einen Bereich unkentlich zu machen mit einen Verschwimmeffekt, hat er mich mit seinen Skript inspiriert. Ich habe es dann noch etwas verfeinert und als Funktion verpackt, sodass man nur noch ein Befehl eingeben muss für diesen Effekt.

Hier mal der Code dazu:

######################
# Verschwimmeffekt auf einen Bereich im Bild
# -------------------------------------------------
# Function Verschwimm (clip clip0, int sw, int sh, int ew, int eh, float px, int faktor, int sframe, int eframe) 
# clip0 = Der Clip der geladen wird
# sw, sh, ew, eh = Bildbereich (x,y) - (x2,y2)
# px = der p Wert für den Gaussresizer. 1 = Unscharf, 100 = scharf
# faktor = Der Faktor mit dem verkleinert wird um das Bild unkenntlich zu machen
# sframe und eframe = Start und Ende des Framebereiches auf dem der Filter angewendet wird
######################


AVISource("L:\Test\Testaufnahme\Aladdin.avi")


#Wenn last alleine ist, muss das Video nicht mit last angegeben werden
#Hier sorgt AVISource dafür das der Clip in last kommt. Somit brauch ich kein Clip angeben
#Verschwimm( clip "Video", x1, y1, x2, y2, px, faktor, frame_start, frame_end)
Verschwimm(374, 54, 650, 126, 1, 40, 1389, 5849)
Verschwimm(374, 54, 650, 126, 1, 40, 6169, 7313)


Function Verschwimm (clip clip0, int sw, int sh, int ew, int eh, float px, int faktor, int sframe, int eframe) {
    clip1 = (sframe == 1) ? clip0.Trim(0, sframe-2) :  clip0.Trim(0, sframe-1)
    clip2 = (faktor == 0) ? clip0.Crop(sw, sh, ew, eh) : clip0.GaussResize(clip0.width / faktor, clip0.height / faktor, sw, sh, -clip0.width + ew, -clip0.height + eh, px).Spline64Resize(ew - sw, eh - sh)
    clip2 = Overlay(clip0, clip2, x = sw, y = sh).Trim(sframe, eframe)
    clip3 = clip0.Trim(eframe+1, clip0.framecount-1)
    return (sframe == 0 && eframe == clip0.framecount - 1) ? clip2 : (sframe == 0) ? clip2++clip3 : (eframe == clip0.framecount - 1) ? clip1++clip2 : clip1++clip2++clip3
}

Die Videos sind verschieden codiert.

Die müssen exakt gleich encodiert worden sein.

Außerdem bitte kein DirectShow für Verlustformate benutzen.

FFMPEGSource2 dafür nehmen (File Indexer + FFVideoSource)

LoadPlugin("C:\Programme\megui\tools\ffms\ffms2.dll")
FFVideoSource("deinvideo.mkv", threads=1)

Pfad oben anpassen.

Heute zeige und gebe ich einen recht brauchbaren [lexicon]AVISynth[/lexicon] Effekt. Ihr kennt ja bislang (wenn überhaupt) nur den regulären Fadein und Fadeout Effekt.

Heute gebe ich euch eine andere Form der Überblende. Die sogenannte Seitenblende.

Das Prinzip beruht auf den bereits vorhandenen Beitrag mit dem dynamischen und statischen Alphakanal

Aussehen würde der Übergangseffekt so (Von links nach rechts sich aufbauend):

Downloaden und testen könnt ihr es hier: Alphablend.7z (279KB)

Weitere Informationen in der Info.txt und den dazugehörigen AVS Files.

Benutzung dieses Effekts ist ganz einfach:

Import(D:\Alphablend\Alphablend v2.0.avs")


v1 = AVISource("Video_1.avi").AssumeFPS(30, 1)
v2 = AVISource("Video_2.avi").AssumeFPS(30, 1)


alphablend(v1, v2, $0000FF, 20, $00FF00, 20, "D:\Alphablend\Alpha Effects\Pic_left_to_right.avs")

Da die Übergangs Effekte auf 2 Farben basieren die dann einfach ausgetauscht werden, hab ich die Möglichkeit geboten jedem selbst Effekte mit [lexicon]AVISynth[/lexicon] zu gestalten. Entweder mit [lexicon]Gimp[/lexicon] Bilder erstellen und diese nutzen oder einfach via Skript selbst welche basteln.

Es muss nur von einer Farbe zur anderen gewechselt werden.

Viel Spaß damit.

Ich habe mich seit vorgestern mit einem Plugin beschäftigt wo man aus Tilesets die Pixel oder Pixelblöcke von Videos oder Bildern austauschen kann.

Man kann so ziemlich jede Palette kreieren die man will, so auch eine Matrix Palette wie ihr im Beispielbild sehen könnt. Spielt dann auch ab und sieht so aus als ob der irgendwas berechnet xD

Natülich habe ich mich auch mit anderen Paletten beschäftigt wie ihr sehen könnt. Vor allem da ich mit @De-M-oN erst letztens über Pixel Shader unterhalten hatten und CGA und EGA in den Raum flogen.

Also habe ich dan dieses Tileset Plugin (TurnsTile so der Name) genommen und selbst dazu ein Plugin geschrieben das die Paletten vorgibt schon.

Das heißt ihr könnt eure Videos in VGA, EGA, CGA, C64, MDA und in eine Matrix Palette jetzt umkonvertieren
Das ganze geht über [lexicon]AVISynth[/lexicon] dann wieder.

Download: Mirror

Installiert am besten die Font zuerst die im Font Unterordner der Zip Datei ist. Es handelt sich um den Matrixfont der für die Matrixansicht benötigt wird.

Ihr bindet das Plugin via Import ein

Import("ConvertToColor.avsi")

und habt dann folgenden neuen Befehl:

ConvertToColor(clip, pal, palreturn, mode, palette)
===================================================
clip       - Video oder Bild
pal        - EXT, EGA, CGA, C64, MDA - Default = EGA
palreturn  - True = Gibt die aktuelle Palette als Bild aus
             False = Gibt den Clip zurück mit der entsprechenden Palettenkonvertierung (Default)
mode       - CGA mode 0 = 6te Farbe ist Braun
                 mode 1 = 6te Farbe ist Dunkelgelb
             MDA mode 0 = Schwarz und Weiß
                 mode 1 = Schwarz und Grün
palette    - In Kombination mit pal = EXT. Ladet eine externe Tileset Paletten Bild.
             Ist Palette = "" (Standard), dann wird statt EXT EGA genommen und angezeigt.

Das ganze sieht in einem normalen Skript dann so aus:

Import("D:\AVISynth_Kram\Plugins\ConvertToColor.avsi")


AVISource("D:\Testaufnahme.avi").AssumeFPS(30, 1)


ConvertToColor("C64")


# Oder


ConvertToColor("Matrix")


# Oder


ConvertToColor("EXT", false, 0, "D:\AVISynth_Kram\Plugins\paletts\rrggbbss.png") # VGA

Das ganze kann etwas dauern bis er alles zusammen hat. Aber es sieht auf jedenfall sehr gut aus.

Für ein paar kleine Spielerein doch recht interessant

Ich will die [lexicon]Doom[/lexicon] Palette

Musste dir die halt erstellen xD
16x16 Tileset pro Farbe.